Skip to page contents

[Installation • Overview • Example Script • Read or Write an Image • Manipulate an Image • Set an Image Attribute • Get an Image Attribute • Create an Image Montage • Working with Blobs • Miscellaneous Methods • Handling Exceptions]

PerlMagick is an objected-oriented Perl interface to ImageMagick. Use the module to read, manipulate, or write an image or image sequence from within a Perl script. This makes it very suitable for Web CGI scripts. You must have ImageMagick 6.2.0 or above and Perl version 5.005_02 or greater installed on your system for either of these utilities to work.

There are a number of useful scripts available to show you the value of PerlMagick. You can do Web based image manipulation and conversion with MagickStudio, or use L-systems to create images of plants using mathematical constructs, and finally navigate through collections of thumbnail images and select the image to view with the WebMagick Image Navigator.

You can try PerlMagick from your Web browser at the ImageMagick Studio. Or, you can see examples of select PerlMagick functions.

UNIX

The following instructions for Unix apply only to the unbundled PerlMagick as obtained from CPAN. PerlMagick is included as a subdirectory (PerlMagick) of the ImageMagick source distribution, and may be configured and built using the instructions provided in the ImageMagick distribution's README.txt file. It is usually most convenient to install PerlMagick as part of the ImageMagick distribution.

ImageMagick must already be installed on your system. Next, get the PerlMagick distribution corresponding to the installed ImageMagick distribution (e.g. PerlMagick 6.22 for ImageMagick 6.2.2) and unpack it as shown below:

  gunzip -c PerlMagick-6.22.tar.gz • tar -xvf -
  cd PerlMagick

Next, edit Makefile.PL and change LIBS and INC to include the appropriate path information to the required libMagick library. You will also need paths to JPEG, PNG, TIFF, etc. delegates if they were included with your installed version of ImageMagick. Build and install it like this:

  perl Makefile.PL
  make
  make install

For Unix, you typically need to be root to install the software. There are ways around this. Consult the Perl manual pages for more information.

Windows XP / Windows 2000

ImageMagick must already be installed on your system. Also, the ImageMagick source distribution for Windows 2000 is required. You must also have the nmake from the Visual C++ or J++ development environment. Copy \bin\IMagick.dll and \bin\X11.dll to a directory in your dynamic load path such as c:\perl\site\5.00502.

Next, type

  cd PerlMagick
  copy Makefile.nt Makefile.PL
  perl Makefile.PL
  nmake
  nmake install

See the PerlMagick Windows HowTo page for further installation instructions.

Running the Regression Tests

To verify a correct installation, type

  make test

Use nmake test under Windows. There are a few demonstration scripts available to exercise many of the functions PerlMagick can perform. Type

  cd demo
  make

You are now ready to utilize the PerlMagick methods from within your Perl scripts.

Any script that wants to use PerlMagick methods must first define the methods within its namespace and instantiate an image object. Do this with:

  use Image::Magick;

  $image=Image::Magick->new;

The new() method takes the same parameters as SetAttribute . For example,

  $image=Image::Magick->new(size=>'384x256');

Next you will want to read an image or image sequence, manipulate it, and then display or write it. The input and output methods for PerlMagick are defined in Read or Write an Image. See Set an Image Attribute for methods that affect the way an image is read or written. Refer to Manipulate an Image for a list of methods to transform an image. Get an Image Attribute describes how to retrieve an attribute for an image. Refer to Create an Image Montage for details about tiling your images as thumbnails on a background. Finally, some methods do not neatly fit into any of the categories just mentioned. Review Miscellaneous Methods for a list of these methods.

Once you are finished with a PerlMagick object you should consider destroying it. Each image in an image sequence is stored in virtual memory. This can potentially add up to mega-bytes of memory. Upon destroying a PerlMagick object, the memory is returned for use by other Perl methods. The recommended way to destroy an object is with undef:

  undef $image;

To delete all the images but retain the Image::Magick object use

  @$image = ();

and finally, to delete a single image from a multi-image sequence, use

  undef $image->[$x];

The next section illustrates how to use various PerlMagick methods to manipulate an image sequence.

Some of the PerlMagick methods require external programs such as Ghostscript. This may require an explicit path in your PATH environment variable to work properly. For example,

  $ENV{PATH}='/../bin:/usr/bin:/usr/local/bin';

Here is an example script to get you started:

  #!/usr/local/bin/perl
  use Image::Magick;

  my($image, $x);

  $image = Image::Magick->new;
  $x = $image->Read('girl.png', 'logo.png', 'rose.png');
  warn "$x" if "$x";

  $x = $image->Crop(geometry=>'100x100+100+100');
  warn "$x" if "$x";

  $x = $image->Write('x.png');
  warn "$x" if "$x";

The script reads three images, crops them, and writes a single image as a GIF animation sequence. In many cases you may want to access individual images of a sequence. The next example illustrates how this is done:

  #!/usr/local/bin/perl
  use Image::Magick;

  my($image, $p, $q);

  $image = new Image::Magick;
  $image->Read('x1.png');
  $image->Read('j*.jpg');
  $image->Read('k.miff[1, 5, 3]');
  $image->Contrast();
  for ($x = 0; $image->[$x]; $x++)
  {
    $image->[$x]->Frame('100x200') if $image->[$x]->Get('magick') eq 'GIF';
    undef $image->[$x] if $image->[$x]->Get('columns') < 100;
  }
  $p = $image->[1];
  $p->Draw(stroke=>'red', primitive=>'rectangle', points=>20,20 100,100');
  $q = $p->Montage();
  undef $image;
  $q->Write('x.miff');

Suppose you want to start out with a 100 by 100 pixel white canvas with a red pixel in the center. Try

  $image = Image::Magick->new;
  $image->Set(size=>'100x100');
  $image->ReadImage('xc:white');
  $image->Set('pixel[49,49]'=>'red');

Or suppose you want to convert your color image to grayscale:

  $image->Quantize(colorspace=>'gray');

Here we annotate an image with a Taipai TrueType font:

  $text = 'Works like magick!';
  $image->Annotate(font=>'kai.ttf', pointsize=>40, fill=>'green', text=>$text);

Perhaps you want to extract all the pixel intensities from an image and write them to STDOUT:

  @pixels = $image->GetPixels(map=>'I', height=>$height, width=>$width, normalize=>true);
  binmode STDOUT;
  print pack('B*',join('',@pixels));

Other clever things you can do with a PerlMagick objects include

  $i = $#$p"+1";   # return the number of images associated with object p
  push(@$q, @$p);  # push the images from object p onto object q
  @$p = ();        # delete the images but not the object p
  $p->Convolve([1, 2, 1, 2, 4, 2, 1, 2, 1]);   # 3x3 Gaussian kernel

Use the methods listed below to either read, write, or display an image or image sequence:

For convenience, methods Write(), Display(), and Animate() can take any parameter that SetAttribute knows about. For example,

  $image->Write(filename=>'image.png', compression=>'None');

Use - as the filename to method Read() to read from standard in or to method Write() to write to standard out:

  binmode STDOUT;
  $image->Write('png:-');

To read an image in the GIF format from a PERL filehandle, use:

  $image = Image::Magick->new;
  open(IMAGE, 'image.gif');
  $image->Read(file=>\*IMAGE);
  close(IMAGE);

To write an image in the PNG format to a PERL filehandle, use:

  $filename = "image.png";
  open(IMAGE, ">$filename");
  $image->Write(file=>\*IMAGE, filename=>$filename);
  close(IMAGE);

If %0Nd, %0No, or %0Nx appears in the filename, it is interpreted as a printf format specification and the specification is replaced with the specified decimal, octal, or hexadecimal encoding of the scene number. For example,

  image%03d.miff

converts files image000.miff, image001.miff, etc.

You can optionally add Image to any method name. For example, ReadImage() is an alias for method Read().

Once you create an image with, for example, method ReadImage() you may want to operate on it. Below is a list of all the image manipulations methods available to you with PerlMagick. There are examples of select PerlMagick methods. Here is an example call to an image manipulation method:

  $image->Crop(geometry=>'100x100+10+20');
  $image->[$x]->Frame("100x200");

And here is a list of other image manipulation methods you can call:

Note, that the geometry parameter is a short cut for the width and height parameters (e.g. geometry=>'106x80' is equivalent to width=>106, height=>80 ).

You can specify @filename in both Annotate() and Draw(). This reads the text or graphic primitive instructions from a file on disk. For example,

   $image->Draw(fill=>'red', primitive=>'rectangle',
     points=>'20,20 100,100  40,40 200,200  60,60 300,300');

Is equivalent to

   $image->Draw(fill=>'red', primitive=>'@draw.txt');

Where draw.txt is a file on disk that contains this:

  rectangle 20, 20 100, 100
  rectangle 40, 40 200, 200
  rectangle 60, 60 300, 300

The text parameter for methods, Annotate(), Comment(), Draw(), and Label() can include the image filename, type, width, height, or other image attribute by embedding these special format characters:

   %b   file size
   %c   comment
   %d   directory
   %e   filename extension
   %f   filename
   %g   page geometry
   %h   height
   %i   input filename
   %k   number of unique colors
   %l   label
   %m   magick
   %n   number of scenes
   %o   output filename
   %p   page number
   %q   quantum depth
   %r   image class and colorspace
   %s   scene number
   %t   top of filename
   %u   unique temporary filename
   %w   width
   %x   x resolution
   %y   y resolution
   %z   image depth
   %C   image compression type
   %D   image dispose method
   %O   page offset
   %P   page width and height
   %Q   image compression quality
   %T   image delay
   %@   bounding box
   %#   signature
   %%   a percent sign
   \n   newline
   \r   carriage return

For example,

  text=>"%m:%f %wx%h"

produces an annotation of MIFF:bird.miff 512x480 for an image titled bird.miff and whose width is 512 and height is 480.

You can optionally add Image to any method name. For example, TrimImage() is an alias for method Trim().

Most of the attributes listed above have an analog in convert. See the documentation for a more detailed description of these attributes.

Use method Set() to set an image attribute. For example,

  $image->Set(dither=>'True');
  $image->[$x]->Set(delay=>3);

Where this example uses 'True' and this document says '{True, False}', you can use the case-insensitive strings 'True' and 'False', or you can use the integers 1 and 0.

When you call Get() on a Boolean attribute, Image::Magick returns 1 or 0, not a string.

And here is a list of all the image attributes you can set:

Note, that the geometry parameter is a short cut for the width and height parameters (e.g. geometry=>'106x80' is equivalent to width=>106, height=>80).

SetAttribute() is an alias for method Set().

Most of the attributes listed above have an analog in convert. See the documentation for a more detailed description of these attributes.

Use method Get() to get an image attribute. For example,

  ($a, $b, $c) = $image->Get('colorspace', 'magick', 'adjoin');
  $width = $image->[3]->Get('columns');

In addition to all the attributes listed in Set an Image Attribute , you can get these additional attributes:

GetAttribute() is an alias for method Get().

Most of the attributes listed above have an analog in convert. See the documentation for a more detailed description of these attributes.

Use method Montage() to create a composite image by combining several separate images. The images are tiled on the composite image with the name of the image optionally appearing just below the individual tile. For example,

  $image->Montage(geometry=>'160x160', tile=>'2x2', texture=>'granite:');

And here is a list of Montage() parameters you can set:

Note, that the geometry parameter is a short cut for the width and height parameters (e.g. geometry=>'106x80' is equivalent to width=>106, height=>80).

MontageImage() is an alias for method Montage().

Most of the attributes listed above have an analog in montage. See the documentation for a more detailed description of these attributes.

A blob contains data that directly represent a particular image format in memory instead of on disk. PerlMagick supports blobs in any of these image formats and provides methods to convert a blob to or from a particular image format.

ImageToBlob() returns the image data in their respective formats. You can then print it, save it to an ODBC database, write it to a file, or pipe it to a display program:

  @blobs = $image->ImageToBlob();
  open(DISPLAY,"| display -") || die;
  binmode DISPLAY;
  print DISPLAY $blobs[0];
  close DISPLAY;

Method BlobToImage() returns an image or image sequence converted from the supplied blob:

  @blob=$db->GetImage();
  $image=Image::Magick->new(magick=>'jpg');
  $image->BlobToImage(@blob);

The Append() method append a set of images. For example,

  $p = $image->Append(stack=>{true,false});

appends all the images associated with object $image. By default, images are stacked left-to-right. Set stack to True to stack them top-to-bottom.

The Average() method averages a set of images. For example,

  $p = $image->Average();

averages all the images associated with object $image.

The Clone() method copies a set of images. For example,

  $p = $image->Clone();

copies all the images from object $q to $p. You can use this method for single or multi-image sequences.

The Flatten() method flattens a set of images and returns it. For example,

  $p = $images->Flatten(background=>'none');
  $p->Write('flatten.png');

The sequence of images is replaced by a single image created by composing each image after the first over the first image.

The Fx() method applies a mathematical expression to a set of images and returns the results. For example,

  $p = $image->Fx(expression=>'(g+b)/2.0',channel=>'red');
  $p->Write('fx.miff');

replaces the red channel with the average of the green and blue channels.

See FX, The Special Effects Image Operator for a detailed discussion of this method.

Histogram() returns the unique colors in the image and a count for each one. The returned values are an array of red, green, blue, opacity, and count values.

The Morph() method morphs a set of images. Both the image pixels and size are linearly interpolated to give the appearance of a meta-morphosis from one image to the next:

  $p = $image->Morph(frames=>integer);

where frames is the number of in-between images to generate. The default is 1.

Mosaic() creates an mosaic from an image sequence.

Method Mogrify() is a single entry point for the image manipulation methods (Manipulate an Image). The parameters are the name of a method followed by any parameters the method may require. For example, these calls are equivalent:

  $image->Crop('340x256+0+0');
  $image->Mogrify('crop', '340x256+0+0');

Method MogrifyRegion() applies a transform to a region of the image. It is similar to Mogrify() but begins with the region geometry. For example, suppose you want to brighten a 100x100 region of your image at location (40, 50):

  $image->MogrifyRegion('100x100+40+50', 'modulate', brightness=>50);

Ping() is a convenience method that returns information about an image without having to read the image into memory. It returns the width, height, file size in bytes, and the file format of the image. You can specify more than one filename but only one filehandle:

  ($width, $height, $size, $format) = $image->Ping('logo.png');
  ($width, $height, $size, $format) = $image->Ping(file=>\*IMAGE);
  ($width, $height, $size, $format) = $image->Ping(blob=>$blob);

This is a more efficient and less memory intensive way to query if an image exists and what its characteristics are. PreviewImage() tiles 9 thumbnails of the specified image with an image processing operation applied at varying strengths. This may be helpful pin-pointing an appropriate parameter for a particular image processing operation. Choose from these operations: Rotate, Shear, Roll, Hue, Saturation, Brightness, Gamma, Spiff, Dull, Grayscale, Quantize, Despeckle, ReduceNoise, AddNoise, Sharpen, Blur, Threshold, EdgeDetect, Spread, Solarize, Shade, Raise, Segment, Swirl, Implode, Wave, OilPaint, CharcoalDrawing, JPEG. Here is an example:

  $preview = $image->Preview('Gamma');
  $preview->Display();

To have full control over text positioning you need font metric information. Use

  ($x_ppem, $y_ppem, $ascender, $descender, $width, $height, $max_advance) = $image->QueryFontMetrics(parameters);

Where parameters is any parameter of the Annotate method. The return values are:

• character width
• character height
• ascender
• descender
• text width
• text height
• maximum horizontal advance
• bounds.x1
• bounds.y1
• bounds.x2
• bounds.y2
• origin.x
• origin.y

Use QueryMultilineFontMetrics() to get the maximum text width and height for multiple lines of text.

Call QueryColor() with no parameters to return a list of known colors names or specify one or more color names to get these attributes: red, green, blue, and opacity value.

  @colors = $image->QueryColor();
  ($red, $green, $blue, $opacity) = $image->QueryColor('cyan');
  ($red, $green, $blue, $opacity) = $image->QueryColor('#716bae');

QueryColorname() accepts a color value and returns its respective name or hex value;

    $name = $image->QueryColorname('rgba(80,60,0,0)');

Call QueryFont() with no parameters to return a list of known fonts or specify one or more font names to get these attributes: font name, description, family, style, stretch, weight, encoding, foundry, format, metrics, and glyphs values.

  @fonts = $image->QueryFont();
  $weight = ($image->QueryFont('Helvetica'))[5];

Call QueryFormat() with no parameters to return a list of known image formats or specify one or more format names to get these attributes: adjoin, blob support, raw, decoder, encoder, description, and module.

  @formats = $image->QueryFormat();
  ($adjoin, $blob_support, $raw, $decoder, $encoder, $description, $module) = $image->QueryFormat('gif');

Call MagickToMime() with the image format name to get its MIME type such as images/tiff from tif.

  $mime = $image->MagickToMime('tif');

Use RemoteCommand() to send a command to an already running display or animate application. The only parameter is the name of the image file to display or animate.

  $image->RemoteCommand('image.jpg');

Statistics() returns the image statistics for each channel in the image. The returned values are an array of depth, minima, maxima, mean, and standard deviation values in RGB, CMYK, RGBA, or CMYKA order (depending on the image type).

  @statistics = $image->Statistics();

Finally, the Transform() method accepts a fully-qualified geometry specification for cropping or resizing one or more images. For example,

  $p = $image->Transform(crop=>'100x100');

You can optionally add Image to any method name above. For example, PingImage() is an alias for method Ping().

All PerlMagick methods return an undefined string context upon success. If any problems occur, the error is returned as a string with an embedded numeric status code. A status code less than 400 is a warning. This means that the operation did not complete but was recoverable to some degree. A numeric code greater or equal to 400 is an error and indicates the operation failed completely. Here is how exceptions are returned for the different methods:

Methods which return a number (e.g. Read(), Write()):

  $x = $image->Read(...);
  warn "$x" if "$x";      # print the error message
  $x =~ /(\d+)/;
  print $1;               # print the error number
  print 0+$x;             # print the number of images read

Methods which operate on an image (e.g. Resize(), Crop()):

  $x = $image->Crop(...);
  warn "$x" if "$x";      # print the error message
  $x =~ /(\d+)/;
  print $1;               # print the error number

Methods which return images (Average(), Montage(), Clone()) should be checked for errors this way:

  $x = $image->Montage(...);
  warn "$x" if !ref($x);  # print the error message
  $x =~ /(\d+)/;
  print $1;               # print the error number

Here is an example error message:

  Error 400: Memory allocation failed

Below is a list of error and warning codes:

The following illustrates how you can use a numeric status code:

  $x = $image->Read('rose.png');
  $x =~ /(\d+)/;
  die "unable to continue" if ($1 == ResourceLimitError);